/**
 * "recursive area tiling algorithmen"<br><br>
 * Press mouse bottom left to init again<br><br>
 * Feel free to use / modify this code however you wish.<br> 
 * We would be happy if you would make a reference to <br> 
 * www.looksgood.de and to generative-systeme.de<br>
 * <br>
 * Benedikt Groß & Julia Laub<br>
 * benedikt ät looksgood dot de / julia ät generative-systeme dot de<br>
 */

void setup()
{
  size(400, 400);
  smooth();
  background(255);

  divide(0,0,256,362, 15);
}

void draw() {
}

void mousePressed() {
  background(255); 
  divide(0,0,256,362, 15);
}

void divide(float x1, float y1, float x2, float y2, int depth)
{
  //do recurson untill
  if (depth<1)
    return;

  int horOrVert = round(random(10));//tiling vertical or horicontal
  int count = (int)random(1,3);//each tile divide in n parts
  depth -= 1;//increment

  //tiling vertical or horicontal
  if (horOrVert < 4) {
    float x_width = abs(x2-x1)/count;
    if (x_width < 1.8) count = 1;
    for (int i=0; i<count; i++)
    {
      x_width = abs(x2-x1)/count;
      //println(depth+" "+count+" "+x_width);
      float xA,xB;
      xA = x1+x_width*i;
      xB = x1+x_width*(i+1);
      divide(xA, y1, xB, y2, depth);
    }
  } 
  else {
    float y_height = abs(y2-y1)/count;
    if (y_height < 0.4) count = 1;
    for (int i=0; i<count; i++)
    {
      y_height = abs(y2-y1)/count;      
      float yA,yB;
      yA = y1+y_height*i;
      yB = y1+y_height*(i+1);
      divide(x1, yA, x2, yB, depth);
    }
  }
  //draw tiles
  if (depth<1) {
    //ellipse(x1,y1,10,10);
    //ellipse(x2,y2,15,15);
    fill(random(255));
    beginShape();
    vertex(x1, y1);
    vertex(x2, y1);
    vertex(x2, y2);
    vertex(x1, y2);
    endShape(CLOSE);
  }

}